Dist-Zilla-Plugin-DynamicPrereqs/t/10-raw-from-file.t
use strict;
use warnings;
use Test::More 0.88;
use if $ENV{AUTHOR_TESTING}, 'Test::Warnings';
use Test::DZil;
use Test::Fatal;
use Path::Tiny;
use Test::Deep;
use Test::Deep::JSON;
use lib 't/lib';
use Helper;
use Test::File::ShareDir
-share => { -module => { 'Dist::Zilla::Plugin::DynamicPrereqs' => 'share/DynamicPrereqs' } };
my $tzil = Builder->from_config(
{ dist_root => 'does-not-exist' },
{
add_files => {
path(qw(source dist.ini)) => simple_ini(
[ GatherDir => ],
[ MetaJSON => ],
[ Prereqs => { 'strict' => '0', 'Test::More' => '0' } ],
[ MakeMaker => ],
[ DynamicPrereqs => { -raw_from_file => 'Makefile.args' } ],
),
path(qw(source lib Foo.pm)) => "package Foo;\n1;\n",
path(qw(source Makefile.args)) => <<'ARGS',
$WriteMakefileArgs{PREREQ_PM}{'Test::More'} = $FallbackPrereqs{'Test::More'} = '0.123'
if eval { require Test::More; 1 };
ARGS
},
},
);
$tzil->chrome->logger->set_debug(1);
is(
exception { $tzil->build },
undef,
'build proceeds normally',
) or diag 'got log messages: ', explain $tzil->log_messages;
my $build_dir = path($tzil->tempdir)->child('build');
# we intentionally test META.json not $tzil->distmeta, for comparability to
# the MYMETA.json test below.
my $meta_json = $build_dir->child('META.json')->slurp_raw;
cmp_deeply(
$meta_json,
json(superhashof({
dynamic_config => 1,
prereqs => {
configure => {
requires => {
'ExtUtils::MakeMaker' => ignore,
},
},
runtime => {
requires => {
'strict' => '0',
'Test::More' => '0',
},
},
},
})),
'dynamic_config set to 1 in metadata; static prereqs are in place',
)
or diag "found META.json content:\n", $meta_json;
my $file = $build_dir->child('Makefile.PL');
ok(-e $file, 'Makefile.PL created');
my $makefile = $file->slurp_utf8;
unlike($makefile, qr/[^\S\n]\n/, 'no trailing whitespace in modified file');
my $version = Dist::Zilla::Plugin::DynamicPrereqs->VERSION;
isnt(
index(
$makefile,
<<CONTENT),
);
# inserted by Dist::Zilla::Plugin::DynamicPrereqs $version
\$WriteMakefileArgs{PREREQ_PM}{'Test::More'} = \$FallbackPrereqs{'Test::More'} = '0.123'
if eval { require Test::More; 1 };
CONTENT
-1,
'code inserted via -raw_from_file into Makefile.PL generated by [MakeMaker]',
) or diag "found Makefile.PL content:\n", $makefile;
ok(!-e $build_dir->child('Makefile.args'), 'arg file was removed from the build');
run_makemaker($tzil);
my $mymeta_json = $build_dir->child('MYMETA.json')->slurp_raw;
cmp_deeply(
$mymeta_json,
json(superhashof({
dynamic_config => 0,
prereqs => subhashof({
configure => {
requires => {
'ExtUtils::MakeMaker' => ignore,
},
},
runtime => {
requires => {
'strict' => '0',
'Test::More' => '0.123',
},
},
build => ignore, # added by [MakeMaker]; removed if
test => ignore, # EUMM version <= 6.63_02
}),
})),
'dynamic_config reset to 0 in MYMETA; dynamic prereqs have been added',
)
or diag "found MYMETA.json content:\n", $mymeta_json,
"found Makefile.PL content:\n", $makefile;
diag 'got log messages: ', explain $tzil->log_messages
if not Test::Builder->new->is_passing;
done_testing;